دوره آموزش آردوینو پیشرفته

				
					#define pirPin 2 // تعریف پایه‌ای که سنسور PIR به آن متصل است
int calibrationTime = 30; // زمان کالیبراسیون اولیه (بر حسب ثانیه)
long unsigned int lowIn; // ذخیره زمان شروع وضعیت "بدون حرکت" سنسور
long unsigned int pause = 5000; // مقدار وقفه (۵ ثانیه) قبل از تشخیص پایان حرکت
boolean lockLow = true; // قفل برای وضعیت LOW (بدون حرکت)
boolean takeLowTime; // کنترل برای ثبت زمان آغاز حالت LOW
int PIRValue = 0; // مقدار خروجی سنسور (۰: بدون حرکت، ۱: حرکت)

void setup() {
   Serial.begin(9600); // شروع ارتباط سریال با نرخ انتقال 9600
   pinMode(pirPin, INPUT); // تنظیم پایه سنسور PIR به عنوان ورودی
}

void loop() {
   PIRSensor(); // فراخوانی تابع برای بررسی وضعیت سنسور PIR
}

void PIRSensor() {
   if (digitalRead(pirPin) == HIGH) { // بررسی اینکه آیا سنسور حرکت تشخیص داده است
      if (lockLow) { // بررسی اینکه آیا وضعیت LOW قبلاً قفل شده است
         PIRValue = 1; // تنظیم مقدار سنسور به ۱ (حرکت تشخیص داده شده)
         lockLow = false; // باز کردن قفل وضعیت LOW
         Serial.println("Motion detected."); // نمایش پیام "تشخیص حرکت"
         delay(50); // تاخیر برای پایداری
      }
      takeLowTime = true; // تنظیم اینکه زمان LOW بعداً ذخیره شود
   }
   if (digitalRead(pirPin) == LOW) { // بررسی اینکه آیا سنسور در حالت "بدون حرکت" است
      if (takeLowTime) { // اگر زمان LOW باید ذخیره شود
         lowIn = millis(); // ذخیره زمان فعلی
         takeLowTime = false; // ذخیره زمان فقط یک‌بار انجام شود
      }
      if (!lockLow && millis() - lowIn > pause) { // اگر حرکت متوقف شده و وقفه ۵ ثانیه گذشته باشد
         PIRValue = 0; // تنظیم مقدار سنسور به ۰ (بدون حرکت)
         lockLow = true; // قفل وضعیت LOW دوباره فعال شود
         Serial.println("Motion ended."); // نمایش پیام "پایان حرکت"
         delay(50); // تاخیر برای پایداری
      }
   }
}